@ECHO OFF
Title FXR Wireless Profile Information
::Assembled by F1X3R

setlocal
setlocal enabledelayedexpansion

CLS
COLOR 0A
ECHO.
ECHO     _/_/_/_/  _/   _/  _/_/_/    
ECHO    _/         _/ _/   _/    _/   
ECHO   _/_/_/      _/     _/_/_/      
ECHO  _/         _/ _/   _/    _/     
ECHO _/        _/   _/  _/    _/      
ECHO.

:LOCALWIFI
    ECHO Wireless Profile Name               Wireless Passphrase
    ECHO ---------------------               -------------------
    SET "spaces=                                        "
    FOR /F "tokens=2 delims=:" %%a IN ('netsh wlan show profile') DO (
        SET wifi_pwd=
        FOR /F "tokens=2 delims=: usebackq" %%F IN (`netsh wlan show profile %%a key^=clear ^| findstr "Key Content"`) DO (
            SET wifi_pwd=%%F
        )
        CALL :PrintAligned "%%a" "!wifi_pwd!"
    )
ECHO.
ECHO.
    PAUSE

:END
    endlocal
    COLOR
    TITLE Command Prompt
    EXIT /B 1

:PrintAligned
    SET "spaces=                                                  "
    SET "wifi_name=%~1"
    SET "passphrase=%~2"
    SET "paddedname=%wifi_name%%spaces%"
    ECHO !paddedname:~0,35! %passphrase%
    GOTO :EOF